Skip to content

How to log data to Thingspeak

🚧 THIS ZONE IS UNDER CONSTRUCTION 🚧

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
/*
  Adapted from WriteSingleField Example from ThingSpeak Library (Mathworks) and Random Nerd Tutorials

  Updated to use LSM6DSOX IMU instead of BME280 sensor
  Logs temperature from IMU sensor in Fahrenheit
*/

#include <WiFi.h>
#include "ThingSpeak.h"
#include <Adafruit_LSM6DSOX.h>
#include <Adafruit_Sensor.h>

const char* ssid = "YOUR-SSID-HERE";   // your network SSID (name) 
const char* password = "YOUR-PASSWORD-HERE";   // your network password

WiFiClient  client;

unsigned long myChannelNumber = 1;
const char * myWriteAPIKey = "YOUR-WRITE-API-KEY-HERE";

// Timer variables
unsigned long lastTime = 0;
unsigned long timerDelay = 30000;

// Variable to hold temperature readings
float temperatureF;

// Create IMU sensor object
Adafruit_LSM6DSOX lsm6dso;

void initIMU(){
  // Initialize IMU-related pins
  pinMode(6, OUTPUT);
  digitalWrite(6, HIGH);

  // Initialize I2C
  Wire.begin(3, 4);
  delay(100);

  Serial.println("Attempting to initialize LSM6DSOX...");
  if (!lsm6dso.begin_I2C()) {
    Serial.println("Failed to find LSM6DSOX chip");
    Serial.println("Check your wiring!");
    while (1) {
      delay(10);
    }
  }

  Serial.println("LSM6DSOX Found!");

  // Configure IMU settings
  lsm6dso.setAccelRange(LSM6DS_ACCEL_RANGE_2_G);
  lsm6dso.setGyroRange(LSM6DS_GYRO_RANGE_250_DPS);
  lsm6dso.setAccelDataRate(LSM6DS_RATE_104_HZ);
  lsm6dso.setGyroDataRate(LSM6DS_RATE_104_HZ);
}

void setup() {
  Serial.begin(115200);  //Initialize serial
  initIMU();

  WiFi.mode(WIFI_STA);   

  ThingSpeak.begin(client);  // Initialize ThingSpeak
}

void loop() {
  if ((millis() - lastTime) > timerDelay) {

    // Connect or reconnect to WiFi
    if(WiFi.status() != WL_CONNECTED){
      Serial.print("Attempting to connect");
      while(WiFi.status() != WL_CONNECTED){
        WiFi.begin(ssid, password); 
        delay(5000);     
      } 
      Serial.println("\nConnected.");
    }

    // Get new IMU sensor readings
    sensors_event_t accel;
    sensors_event_t gyro;
    sensors_event_t tempEvent;
    lsm6dso.getEvent(&accel, &gyro, &tempEvent);

    // Get temperature in Fahrenheit
    temperatureF = (tempEvent.temperature * 1.8) + 32;
    Serial.print("Temperature (ºF): ");
    Serial.println(temperatureF);

    // Write to ThingSpeak. There are up to 8 fields in a channel, allowing you to store up to 8 different
    // pieces of information in a channel.  Here, we write to field 1.
    int x = ThingSpeak.writeField(myChannelNumber, 1, temperatureF, myWriteAPIKey);

    if(x == 200){
      Serial.println("Channel update successful.");
    }
    else{
      Serial.println("Problem updating channel. HTTP error code " + String(x));
    }
    lastTime = millis();
  }
}